Shader | 01基本光照模型浅析Diffuse | 游戏资源 | 元素文章 | 游戏开发 | 微元素 - Diffuse,Shader,技术,渲染,代码,Thepoly

您需要登录才可以下载或查看，没有账号？注册

x

Hello . 大家好

今天带来的是基本光照模型浅析

我是麦田

前天在狼主技术群里，有一个朋友问了一个问题：

更多精彩图片请登录

所以今天就来给大家详解一下标准光照模型。写在前面：很多技术点是借鉴了冯乐乐女神的Shader精要内的，我不过是拾人牙慧而已，这种圣书推荐大家人手一本。

更多精彩图片请登录

兰伯特定律：反射光线的强度与表面法线和光源方向之间的夹角余弦值成正比。而漫反射是符合兰伯特定律的。

在没有BRDF（双向分布反射函数）之前，标准的光照模型早就被广泛的使用了。乍一看有点难理解，仔细想想。

更多精彩图片请登录

看一下这张图，回忆一下初高中学的cos/sin，来看一下公式：

Cdiffuse =( Clight * Mdiffuse )max(0,dot(N,L)）

其中：Clight 是光源的颜色；Mdiffuse是材质的漫反射颜色；N是归一化后的法线（倒三角符号试了半天没打出来）；L是光源单位矢量（即光源方向）；MAX是为了不要取到负值，将它映射到一个范围内，通常这个范围是0-1，Shader内有一个saturate函数可以直接使用。

此时，我们还需要牵扯到一个概念，即环境光：ambient

什么是环境光呢？如果说，太阳是一个直接光源，照射到了一个红苹果，然后红苹果下面有个绿布，那么红苹果和绿布交接的阴影和投影会被互相影响到。这就是环境光，也被称为间接光照。

环境光照公式非常简单，因为他是一个全局变量，就是说，整个场景内都是使用的这个环境光，等式如下：

Cambient = Gambient

一个函数：saturate（x）x：可以是标量或者矢量，也可以是float1，2，3类型干嘛用的呢？上文提到过；即MAX，钳制范围在（0，1）

下面我就就开始上实战的代码，这里我直接贴了女神的代码，我在后面逐句写了注释。

逐像素光照与逐顶点光照

逐顶点光照

Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level" {
// 定义Shader的路径和名称，以斜杠分割
Properties {
// Properties语义块，用来声明属性
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
// 这里声明了一个颜色属性，默认值为白色
}
SubShader {
Pass {
定义一个PASS语义
Tags { "LightMode"="ForwardBase" }
// 我们设置一个标签，设置他的渲染路径为前向渲染，lightMode会计算环境光，平行光等
CGPROGRAM
// CGPROGRAM...ENDCG，这个语义内是Cg/HLSL语言
#pragma vertex vert
#pragma fragment frag
// 告诉Unity，顶点和片元分别叫什么
#include "Lighting.cginc"
// 包含一个内置变量Lighting.cginc,可以通过去官网下载Unity内置Shader看看到底做了什么
fixed4 _Diffuse;
// 我们在Properties中声明了一个属性，现在我们要给这个属性赋值，给他一个fixed4的变量
// 因为color是RGBA，四个通道，平时用PS时是0-255，这里我们是映射0-1的
struct a2v {
// 输入结构体 a2v为输入结构体的名称
float4 vertex : POSITION;
float3 normal : NORMAL;
//访问顶点位置和法线，把模型顶点法线信息存到normal变量内
};
struct v2f {
// 输出结构体，同时也是片元着色器的输入结构体
float4 pos : SV_POSITION;
fixed3 color : COLOR;
// 定义一个颜色变量，把我们获得的信息传递给片元着色器
};
// 接下来就是算法部分了
v2f vert(a2v v) {
v2f o;
// 定义一个返回值o
o.pos = UnityObjectToClipPos(v.vertex);
// 把顶点位置从模型空间转换到其次裁剪空间，这里要注意的是
// 自2017之后，这里的坐标转换变量改成了上文
// 获得光源颜色，强度和方向。
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// 下面就是点积过程，我们要将他们转化到统一坐标系，只有这样，点积才有意义
//将物体法线转换到世界空间下并进行归一化，首先我们要先得到模型到空间变化矩阵的逆矩阵
//这里要注意一下17往后的语义改了，原为_World2Object
fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
// 获取世界空间下的法线和光源方向后，们要进行一次归一化
fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
// 我们将世界空间光和世界空间法向量Dot（点积），然后使用saturate钳制输出范围0-1，这一步就对应了公式
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
// 最后，我们将环境光和漫反射相加后输出
o.color = ambient + diffuse;
return o;
}
逐顶点光照基本都是在顶点着色器内完成的，片元着色器内只需要输出就好
fixed4 frag(v2f i) : SV_Target {
return fixed4(i.color, 1.0);
//（i。color可以理解为RGB。1.0即为A通道）
}
ENDCG
//CG语句结束
}
}
FallBack "Diffuse"
//最后我们留一个后门，防止在有些平台上变成小粉红，这里我们就指向默认
}

点击此处复制文本

逐像素光照

Shader "Unity Shaders Book/Chapter 6/Diffuse Pixel-Level" {
Properties {
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
}
SubShader {
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
};
v2f vert(a2v v) {
v2f o;
// Transform the vertex from object space to projection space
o.pos = UnityObjectToClipPos(v.vertex);
// Transform the normal from object space to world space
o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
return o;
}
fixed4 frag(v2f i) : SV_Target {
// Get ambient term
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
// Get the normal in world space
fixed3 worldNormal = normalize(i.worldNormal);
// Get the light direction in world space
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
// Compute diffuse term
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
fixed3 color = ambient + diffuse;
return fixed4(color, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}