Unity Shader | 遮挡透视显示解决方案

登录

TA资源类型
TA资源类型:	算法思路
shader资源类型:	shader代码
适用引擎:	unity
资源介绍:	转自又不是非我不可 https://zhuanlan.zhihu.com/p/495772145

上一个

Genshin Impact 角色材质着色器

下一个

雪花

您需要登录才可以下载或查看，没有账号？注册

x

效果图

x - ray 透视效果

原理

物体被遮挡 --> 深度测试不通过
深度测试通过的部分用普通光照pass
深度测试不通过的部分用透视着色pass

伪代码

Pass
{
//深度测试通过的pass
//普通光照着色
//...
}
Pass
{
//深度测试不通过的pass
//为了使被遮挡的部分被绘制, 则修改深度测试规则
ZTest Greater
//...
}

点击此处复制文本

代码

Shader "ZLearn/SimpleAlpha_XRay"
{
Properties
{
[HDR]_XRayCol ("XRay Color", Color) = (1, 1, 1, 1)
_XRayFresPow ("XRay Fresnel Pow", Float) = 5
}
SubShader
{
//lighting pass
Pass
{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fwdbase
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float3 wNor : TEXCOORD1;
};
float _Alpha;
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord;
o.wNor = UnityObjectToWorldNormal(v.normal);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
float3 lDir = normalize(_WorldSpaceLightPos0.xyz);
float LdN = dot(lDir, i.wNor);
fixed4 col = 1;
col.xyz = LdN * 0.5 + 0.5;//用简单的半兰伯特光照模型
return col;
}
ENDCG
}
//x ray pass
Pass
{
Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "IgnoreProjector" = "True"}
Blend SrcAlpha OneMinusSrcAlpha
ZWrite Off
Cull Back
ZTest Greater
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float3 wNor : TEXCOORD1;
float3 wPos : TEXCOORD2;
};
float4 _XRayCol;
float _XRayFresPow;
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord;
o.wNor = UnityObjectToWorldNormal(v.normal);
o.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.wPos);
float fres = dot(vDir, i.wNor);
fres = pow(1 - fres, _XRayFresPow);
fixed4 col = fres * _XRayCol;
col.a = saturate(col.a);
return col;
}
ENDCG
}
}
}

点击此处复制文本

虽然被其他物体遮挡的部分有了透视效果, 但自身遮挡自身的部分, 也出现了不希望的透视效果

自遮挡解决方案

使用模板测试stencil https://docs.unity.cn/cn/current/Manual/SL-Stencil.html
第一个pass先在自身所覆盖的像素对应buffer写入模板
使第二个pass模板测试不通过即可, 则可在自身覆盖的像素不会显示自遮挡的透视效果

伪代码

Pass
{
//深度测试通过的pass
//普通光照着色
Stencil
{
Ref 1 //设定值为1
Comp GEqual //该ref值(1)比缓冲中的值大于等于时通过
Pass Replace //通过后写入值
}
//...
}
Pass
{
//深度测试不通过的pass
//为了使被遮挡的部分被绘制, 则修改深度测试规则
ZTest Greater
Stencil
{
Ref 0 //设定值为0
Comp Equal //缓冲的值为0才能通过, pass1中自身覆盖像素模板缓冲为1, 则pass2不会通过
Pass Keep //通过后缓冲值不变
}
//...
}

点击此处复制文本

代码

Shader "ZLearn/SimpleAlpha_XRay"
{
Properties
{
[HDR]_XRayCol ("XRay Color", Color) = (1, 1, 1, 1)
_XRayFresPow ("XRay Fresnel Pow", Float) = 5
}
SubShader
{
//lighting pass
Pass
{
Tags {"LightMode" = "ForwardBase"}
Stencil
{
Ref 1
Comp GEqual //该ref值(1)比缓冲中的值大于等于时通过
Pass Replace
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_fwdbase
#include "UnityCG.cginc"
#include "Lighting.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float3 wNor : TEXCOORD1;
};
float _Alpha;
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord;
o.wNor = UnityObjectToWorldNormal(v.normal);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
float3 lDir = normalize(_WorldSpaceLightPos0.xyz);
float LdN = dot(lDir, i.wNor);
fixed4 col = 1;
col.xyz = LdN * 0.5 + 0.5;//用简单的半兰伯特光照模型
return col;
}
ENDCG
}
//x ray pass
Pass
{
Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "IgnoreProjector" = "True"}
Blend SrcAlpha OneMinusSrcAlpha
ZWrite Off
Cull Back
ZTest Greater
Stencil
{
Ref 0
Comp Equal
Pass Keep
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float3 wNor : TEXCOORD1;
float3 wPos : TEXCOORD2;
};
float4 _XRayCol;
float _XRayFresPow;
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord;
o.wNor = UnityObjectToWorldNormal(v.normal);
o.wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
float3 vDir = normalize(_WorldSpaceCameraPos.xyz - i.wPos);
float fres = dot(vDir, i.wNor);
fres = pow(1 - fres, _XRayFresPow);
fixed4 col = fres * _XRayCol;
col.a = saturate(col.a);
return col;
}
ENDCG
}
}
}

点击此处复制文本

效果

更多精彩图片请登录

Surface Shader

若不想从unlit shader入手, 直接使用pbr shader, 可使用surface shader

Shader "ZLearn/Surf_XRay"
{
Properties
{
_Color ("Color", Color) = (1,1,1,1)
_Glossiness ("Smoothness", Range(0,1)) = 0.5
_Metallic ("Metallic", Range(0,1)) = 0.0
[Space(20)]
[HDR]_XRayCol ("XRay Color", Color) = (1, 1, 1, 1)
_XRayFresPow ("XRay Fresnel Pow", Float) = 5
}
SubShader
{
//lighting pass
Tags { "RenderType" = "Opaque" }
Stencil
{
Ref 1
Comp GEqual
Pass Replace
}
CGPROGRAM
#pragma surface surf Standard fullforwardshadows addshadow
struct Input
{
float2 uv_texcoord;
};
half _Glossiness;
half _Metallic;
fixed4 _Color;
UNITY_INSTANCING_BUFFER_START(Props)
UNITY_INSTANCING_BUFFER_END(Props)
void surf (Input IN, inout SurfaceOutputStandard o)
{
fixed4 c = _Color;
o.Albedo = c.rgb;
o.Metallic = _Metallic;
o.Smoothness = _Glossiness;
o.Alpha = c.a;
}
ENDCG
//x ray pass
Tags { "RenderType" = "Transparent" "Queue" = "Transparent" "IgnoreProjector" = "True"}
Stencil
{
Ref 0
Comp Equal
Pass Keep
}
ZWrite Off
ZTest Greater
CGPROGRAM
#pragma surface surf Standard addshadow fullforwardshadows alpha:fade
struct Input
{
float2 uv_texcoord;
float3 worldPos;
float3 worldNormal;
};
float4 _XRayCol;
float _XRayFresPow;
UNITY_INSTANCING_BUFFER_START(Props)
UNITY_INSTANCING_BUFFER_END(Props)
void surf (Input IN, inout SurfaceOutputStandard o)
{
float3 vDir = normalize(_WorldSpaceCameraPos.xyz - IN.worldPos);
float fres = dot(vDir, IN.worldNormal);
fres = pow(1 - fres, _XRayFresPow);
fixed4 col = fres * _XRayCol;
o.Emission = col.xyz;
o.Alpha = col.a;
}
ENDCG
}
FallBack "Diffuse"
}